Perspective/eyebrowse glue code initial version

modules/em-workflow.el

@@ -20,10 +20,117 @@
 
 (defvar emodule/em-workflow-packages
 
-  '(perspective)
+  '(perspective
+    eyebrowse)
 
   )
 
+(defvar em-workflow/perspectives nil)
+
+(defun get-persp-parameters (persp)
+  "Return alist of parameters for perspective PERSP.
+If the alist did not exist, create one and initialise the values
+to nil."
+  (assoc persp em-workflow/perspectives))
+
+(defun persp-parameter-cons (param-name persp)
+  "Return value of PARAM-NAME for perspective PERSP.
+If none was set, returns nil."
+  (assoc param-name (get-persp-parameters persp)))
+
+(defun persp-parameter (param-name persp)
+  "Return value of PARAM-NAME for perspective PERSP.
+If none was set, returns nil."
+  (cdr (persp-parameter-cons param-name persp)))
+
+(defun set-persp-parameter (param-name value persp)
+  "Set PARAM-NAME to VALUE for perspective PERSP."
+  (let ((param (persp-parameter-cons param-name persp)))
+    (when (not param)
+      (let ((persp-params (get-persp-parameters persp)))
+        (when (not persp-params)
+          (setq em-workflow/perspectives
+                (cons `(,persp . nil) em-workflow/perspectives))
+          (setq persp-params (car em-workflow/perspectives)))
+        (setcdr persp-params
+                (cons `(,param-name . nil) (cdr persp-params)))
+        (setq param (cadr persp-params))))
+    (setcdr param value)))
+
+(defun workspaces/get-persp-workspace (&optional persp frame)
+  "Get the correct workspace parameters for perspective.
+PERSP is the perspective, and defaults to the current
+perspective.  FRAME is the frame where the parameters are
+expected to be used, and defaults to the current frame."
+  (or persp (setq persp (persp-curr)))
+  (let ((param-names (if (display-graphic-p frame)
+                         '(gui-eyebrowse-window-configs
+                           gui-eyebrowse-current-slot
+                           gui-eyebrowse-last-slot)
+                       '(term-eyebrowse-window-configs
+                         term-eyebrowse-current-slot
+                         term-eyebrowse-last-slot))))
+    (--map (persp-parameter it persp) param-names)))
+
+(defun workspaces/set-persp-workspace (workspace-params &optional persp frame)
+  "Set workspace parameters for perspective.
+WORKSPACE-PARAMS should be a list containing 3 elements in
+this order:
+- window-configs, as returned by (eyebrowse--get 'window-configs)
+- current-slot, as returned by (eyebrowse--get 'current-slot)
+- last-slot, as returned by (eyebrowse--get 'last-slot)
+PERSP is the perspective, and defaults to the current
+perspective.  FRAME is the frame where the parameters came from,
+and defaults to the current frame.  Each perspective has two sets
+of workspace parameters: one set for graphical frames, and one
+set for terminal frames."
+  (or persp (setq persp (persp-curr)))
+  (let ((param-names (if (display-graphic-p frame)
+                         '(gui-eyebrowse-window-configs
+                           gui-eyebrowse-current-slot
+                           gui-eyebrowse-last-slot)
+                       '(term-eyebrowse-window-configs
+                         term-eyebrowse-current-slot
+                         term-eyebrowse-last-slot))))
+    (--zip-with (set-persp-parameter it other persp)
+                param-names workspace-params)))
+
+(defun workspaces/load-eyebrowse-for-perspective (&optional frame)
+  "Load an eyebrowse workspace according to a perspective's parameters.
+FRAME's perspective is the perspective that is considered,
+defaulting to the current frame's perspective.  If the
+perspective doesn't have a workspace, create one."
+  (let* ((workspace-params (workspaces/get-persp-workspace (persp-curr frame) frame))
+         (window-configs (nth 0 workspace-params))
+         (current-slot (nth 1 workspace-params))
+         (last-slot (nth 2 workspace-params)))
+    (if window-configs
+        (progn
+          (eyebrowse--set 'window-configs window-configs frame)
+          (eyebrowse--set 'current-slot current-slot frame)
+          (eyebrowse--set 'last-slot last-slot frame)
+          (eyebrowse--load-window-config current-slot))
+      (eyebrowse--set 'window-configs nil frame)
+      (eyebrowse-init frame)
+      (workspaces/save-eyebrowse-for-perspective frame))))
+
+(defun workspaces/update-eyebrowse-for-perspective (&rest _args)
+  "Update and save current frame's eyebrowse workspace to its perspective."
+  (let* ((current-slot (eyebrowse--get 'current-slot))
+         (current-tag (nth 2 (assoc current-slot (eyebrowse--get 'window-configs)))))
+    (eyebrowse--update-window-config-element
+     (eyebrowse--current-window-config current-slot current-tag)))
+  (workspaces/save-eyebrowse-for-perspective))
+
+(defun workspaces/save-eyebrowse-for-perspective (&optional frame)
+  "Save FRAME's eyebrowse workspace to FRAME's perspective.
+FRAME defaults to the current frame."
+  (workspaces/set-persp-workspace (list (eyebrowse--get 'window-configs frame)
+                                        (eyebrowse--get 'current-slot frame)
+                                        (eyebrowse--get 'last-slot frame))
+                                  (persp-curr frame)
+                                  frame))
+
 ;;; Configuration:
 
 (defun emodule/em-workflow-init ()
@@ -37,6 +144,20 @@
     :config
     (persp-mode))
 
+  (use-package eyebrowse
+    :after perspective
+    :config
+    (eyebrowse-mode)
+
+    (add-hook 'persp-before-switch-hook
+              #'workspaces/update-eyebrowse-for-perspective)
+    (add-hook 'eyebrowse-post-window-switch-hook
+              #'workspaces/save-eyebrowse-for-perspective)
+    (add-hook 'persp-activated-hook
+              #'workspaces/load-eyebrowse-for-perspective)
+
+    )
+
   )
 
 (provide 'em-workflow)